Loading:

Ferie zimowe - 3 za 2

Wykrywanie odległości pomiędzy obiektami - animacja łączenia liniami [ AS 3 ]

Skrypt wyświetla losowo poruszające się obiekty, oraz łączy je liniami jeśli zbliżą się na określony dystans do samych siebie.

 

Przykład używa atrybutów takich jak grawitacja oraz masa.

 

Wersja on-line:

 

 



Napisz Artykuł

Listing

//KOD DLA KLASY PolaczeniaKul.as

package {
        import flash.display.Sprite;
        import flash.display.StageScaleMode;
        import flash.display.StageAlign;
        import flash.events.Event;
        import flash.geom.Point;

        [SWF(backgroundColor=0x000000)]
        public class PolaczeniaKul extends Sprite
        {
                private var czastki:Array;
                private var iloscKul:uint = 30;
                private var minimalnyDystans:Number = 100;
                private var iloscOdbicia:Number = .0025;
               
                public function PolaczeniaKul()
                {
                        init();
                }
               
                private function init():void
                {
                        stage.scaleMode = StageScaleMode.NO_SCALE;
                        stage.align = StageAlign.TOP_LEFT;
                        czastki = new Array();
                        for(var i:uint = 0; i < iloscKul; i++)
                        {
                                var wielkosc:Number = Math.random() * 10 + 2;
                                var czastka:Pilka = new Pilka(wielkosc, 0xffffff);
                                czastka.x = Math.random() * stage.stageWidth;
                                czastka.y = Math.random() * stage.stageHeight;
                                czastka.vx = Math.random() * 6 - 3;
                                czastka.vy = Math.random() * 6 - 3;
                                czastka.mass = wielkosc;
                                addChild(czastka);
                                czastki.push(czastka);
                        }
                       
                        addEventListener(Event.ENTER_FRAME, onEnterFrame);
                }

                private function onEnterFrame(event:Event):void
                {
                        graphics.clear();
                        for(var i:uint = 0; i < iloscKul; i++)
                        {
                                var czastka:Pilka = czastki[i];
                                czastka.x += czastka.vx;
                                czastka.y += czastka.vy;
                                if(czastka.x > stage.stageWidth)
                                {
                                        czastka.x = 0;
                                }
                                else if(czastka.x < 0)
                                {
                                        czastka.x = stage.stageWidth;
                                }
                                if(czastka.y > stage.stageHeight)
                                {
                                        czastka.y = 0;
                                }
                                else if(czastka.y < 0)
                                {
                                        czastka.y = stage.stageHeight;
                                }
                        }
                         
                        for(i=0; i < iloscKul - 1; i++)
                        {
                                var czescA:Pilka = czastki[i];
                                for(var j:uint = i + 1; j < iloscKul; j++)
                                {
                                        var czescB:Pilka = czastki[j];
                                        spring(czescA, czescB);
                                }
                        }
                }
               
                private function spring(czescA:Pilka, czescB:Pilka):void
                {
                        var dx:Number = czescB.x - czescA.x;
                        var dy:Number = czescB.y - czescA.y;
                        var dist:Number = Math.sqrt(dx * dx + dy * dy);
                        if(dist < minimalnyDystans)
                        {
                                graphics.lineStyle(1, 0xffffff, 1 - dist / minimalnyDystans);
                                graphics.moveTo(czescA.x, czescA.y);
                                graphics.lineTo(czescB.x, czescB.y);
                                var ax:Number = dx * iloscOdbicia;
                                var ay:Number = dy * iloscOdbicia;
                                czescA.vx += ax / czescA.mass;
                                czescA.vy += ay / czescA.mass;
                                czescB.vx -= ax / czescB.mass;
                                czescB.vy -= ay / czescB.mass;
                        }
                }
        }
}


//KOD DLA KLASY Pilka.as

package {
        import flash.display.Sprite;
       
        public class Pilka extends Sprite {
                public var radius:Number;
                private var color:uint;
                public var vx:Number = 0;
                public var vy:Number = 0;
                public var mass:Number = 1;
               
                public function Pilka(radius:Number=40, color:uint=0xff0000) {
                        this.radius = radius;
                        this.color = color;
                        init();
                }
                public function init():void {
                        graphics.beginFill(color);
                        graphics.drawCircle(0, 0, radius);
                        graphics.endFill();
                }
        }
}


Ten wpis posiada swój wątek na forum

Wszystkie pytania prosimy kierować właśnie tam ponieważ komentarze to miejsce na poprawki do kodu lub alternatywne rozwiązania i pytania nie będą publikowane

http://forum.funkcje.net/forum/viewtopic.php?f=12&t=5276

Dane do logowania na forum są takie same jak na funkcje.net



Dodano przez: divix
Ranga: Administrator serwisu Punktów: 37719
Komentarze użytkowników
    • Treść komentarza
      Kod do komentarza (opcjonalnie)
      PHP JavaScript MySQL Smarty SQL HTML CSS ActionScript
      Autor
      Token
      token

       

       








funkcje.net
Wszelkie prawa zastrzeżone©. | Funkcje.net 2008-17 v.1.5 | design: diviXdesign & rainbowcolors