Klasa: NETStream

Kompatybilność: ActionScript 1.0, Flash 7+

 

Zwraca totalny rozmiar w bajtach ładowanego pliku.

 

Możesz użyć tej metody w połączeniu z NetStream.bytesTotal, aby określić procentową wartość załadowania buferu, na przykald po to, aby wyświetlić poziom załadowania pliku.

var polaczenie_nc:NetConnection = new NetConnection();
polaczenie_nc.connect(null);
var stream_ns:NetStream = new NetStream(polaczenie_nc);
moj_video.attachVideo(stream_ns);
stream_ns.play("video1.flv");

this.createTextField("loaded_txt", this.getNextHighestDepth(), 10, 10, 160, 22);
this.createEmptyMovieClip("progressBar_mc", this.getNextHighestDepth());
progressBar_mc.createEmptyMovieClip("bar_mc", progressBar_mc.getNextHighestDepth());
with (progressBar_mc.bar_mc) {
    beginFill(0xFF0000);
    moveTo(0, 0);
    lineTo(100, 0);
    lineTo(100, 10);
    lineTo(0, 10);
    lineTo(0, 0);
    endFill();
    _xscale = 0;
}
progressBar_mc.createEmptyMovieClip("stroke_mc", progressBar_mc.getNextHighestDepth());
with (progressBar_mc.stroke_mc) {
    lineStyle(0, 0x000000);
    moveTo(0, 0);
    lineTo(100, 0);
    lineTo(100, 10);
    lineTo(0, 10);
    lineTo(0, 0);
}

var loaded_interval:Number = setInterval(checkBytesLoaded, 500, stream_ns);
function checkBytesLoaded(moj_ns:NetStream) {
    var pctLoaded:Number = Math.round(moj_ns.bytesLoaded/moj_ns.bytesTotal*100);
    loaded_txt.text = Math.round(moj_ns.bytesLoaded/1000)+" z "+Math.round(moj_ns.bytesTotal/1000)+" KB załadowano ("+pctLoaded+"%)";
    progressBar_mc.bar_mc._xscale = pctLoaded;
    if (pctLoaded>=100) {
    clearInterval(loaded_interval);
    }
}