Klasa: Sound

Kompatybilność: ActionScript 1.0, Flash 5+

 

Zwraca długość dźwięku, w milisekundach.

// #1 Prosty przykład użycia właściwości duration

var moj_sound:Sound = new Sound();
moj_sound.onLoad = function(success:Boolean) {
    var totalSekundy:Number = this.duration/1000;
    trace(this.duration+" ms ("+Math.round(totalSekundy)+" sekundy)");
    var minuty:Number = Math.floor(totalSekundy/60);
    var sekundy = Math.floor(totalSekundy)%60;
    if (sekundy<10) {
    sekundy = "0"+sekundy;
    }
    trace(minuty+":"+sekundy);
};
moj_sound.loadSound("muzyka1.mp3", true);


// #2 przykład wczytuje kilka dźwięków do pliku SWF. wyświetlany jest rownież pasek postępu.

var pb_height:Number = 10;
var pb_width:Number = 100;
var pb:MovieClip = this.createEmptyMovieClip("progressBar_mc", this.getNextHighestDepth());
pb.createEmptyMovieClip("bar_mc", pb.getNextHighestDepth());
pb.createEmptyMovieClip("vBar_mc", pb.getNextHighestDepth());
pb.createEmptyMovieClip("stroke_mc", pb.getNextHighestDepth());
pb.createTextField("pos_txt", pb.getNextHighestDepth(), 0, pb_height, pb_width, 22);

pb._x = 100;
pb._y = 100;

with (pb.bar_mc) {
    beginFill(0x00FF00);
    moveTo(0, 0);
    lineTo(pb_width, 0);
    lineTo(pb_width, pb_height);
    lineTo(0, pb_height);
    lineTo(0, 0);
    endFill();
    _xscale = 0;
}
with (pb.vBar_mc) {
    lineStyle(1, 0x000000);
    moveTo(0, 0);
    lineTo(0, pb_height);
}
with (pb.stroke_mc) {
    lineStyle(3, 0x000000);
    moveTo(0, 0);
    lineTo(pb_width, 0);
    lineTo(pb_width, pb_height);
    lineTo(0, pb_height);
    lineTo(0, 0);
}

var moj_interval:Number;
var moj_sound:Sound = new Sound();
moj_sound.onLoad = function(success:Boolean) {
    if (success) {
    trace("sound loaded");
    }
};
moj_sound.onSoundComplete = function() {
    clearInterval(moj_interval);
    trace("Cleared interval");
}
moj_sound.loadSound("muzyka3.mp3", true);
moj_interval = setInterval(updateProgressBar, 100, moj_sound);

function updateProgressBar(the_sound:Sound):Void {
    var pos:Number = Math.round(the_sound.position/the_sound.duration*100);
    pb.bar_mc._xscale = pos;
    pb.vBar_mc._x = pb.bar_mc._width;
    pb.pos_txt.text = pos+"%";
}