Klasa: GradientBevelFilter

Kompatybilność: ActionScript 1.0, Flash 8+

 

Wartości kanałów Alpha przezroczystości dla kolorów podanych w tablicy colors w płaskorzeźbie.

 

Dostępne wartości to przedział od 0 do 1, gdzie na przykład 0.25 wskazuje na 25%.

 

Aby zmienić wartości w tej właściwości należy zmienić odwołanie do tablicy.

 

Właściwości colors, alphas oraz ratios są zależne od siebie.

import flash.filters.GradientBevelFilter;

var mc:MovieClip = ustawFiltr("alphasPrzykład");
mc.onPress = function() {
    var arr:Array = this.filters;
    var alphas:Array = [0.2, 0, 0.2];
    arr[0].alphas = alphas;
    this.filters = arr;
}
mc.onRelease = function() {
    var arr:Array = this.filters;
    var alphas:Array = [1, 0, 1];
    arr[0].alphas = alphas;
    this.filters = arr;
}

function ustawFiltr(nazwa:String):MovieClip {
    var art:MovieClip = this.createEmptyMovieClip(nazwa, this.getNextHighestDepth());
    var w:Number = 150;
    var h:Number = 150;
    art.beginFill(0xCCCCCC);
    art.lineTo(w, 0);
    art.lineTo(w, h);
    art.lineTo(0, h);
    art.lineTo(0, 0);
   
    var colors:Array = [0xFFFFFF, 0xCCCCCC, 0x000000];
    var alphas:Array = [1, 0, 1];
    var ratios:Array = [0, 128, 255];
    var filtr:GradientBevelFilter = new GradientBevelFilter(5, 225, colors, alphas, ratios, 5, 5, 5, 2, "inner", false);
   
    art.filters = new Array(filtr);
    return art;
}