Podany skrypt działa wyłącznie w języku ActionScript 3. Kod wczytuje najpierw zewnętrzny plik w tej samej lokalizacji co plik SWF. Potem style zostają przypisane do wygenerowanego pola tekstowego, z włączona opcją formatowania HTML.

INSTRUKCJA UZYCIA:

1. Stwórz plik CSS o nazwie style.css .

2. Skopiuj kod css do pliku CSS.

3. Stwórz nowy plik AS o nazwie StyleCSSDemo.as .

4. Wklej kod ActionScript do pliku AS.

5. Zapisz plik AS oraz CSS.

6. Stwórz nowy plik Flash ActionScript 3 o dowolnej nazwie.

7. W panelu inspektora właściwości, pod polem Klasa dokumenty wpisz: StyleCSSDemo .

8. Naciśnij CTR+ENTER aby przetestować film.

Zwartość pliku style.css

p {
font-family: Arial;
font-size: 20px;
font-weight: bold;
}

Kod ActionScript 3:

package {

 //importowanie rzeczy których używamy w tym kodzie
 import flash.display.Sprite;
 import flash.text.*;
 import flash.events.*;
 import flash.net.*;

 //klasa która zawiera cały skrypt
 public class StyleCSSDemo extends Sprite {
  //konstruktor
  public function StyleCSSDemo () {
  var urlLoader:URLLoader = new URLLoader();
  //odwołanie się do funkcji zaladowanoStyle, gdy plik zostanei wczytany
  urlLoader.addEventListener(Event.COMPLETE, zaladowanoStyle);
  //wczytywanie stylu CSS
  urlLoader.load(new URLRequest("style.css"));
  }
 
  //funkcja do dodawania stylu do tekstu
  private function zaladowanoStyle(e:Event):void {
  var styleCSS:StyleSheet = new StyleSheet();
  //kopiowanie styli do klasy StyleSheet
  styleCSS.parseCSS(e.target.data);

  //tworzenie nowego pola
  var tekst:TextField = new TextField();
  tekst.width = 500;
  //dodawanie stylu
  tekst.styleSheet = styleCSS;
  //dodanie tekstu, pamiętajmy najpierw dodajemy styl potem tekst!
  tekst.htmlText = "<p>Funkcje.net - tekst z obsługą stylu CSS.</p>";
 
  //dodanie tekstu do wyświetlania na scenie
  addChild(tekst);
  }
 }
}