Klasa: DisplacementMapFilter

Kompatybilność: ActionScript 1.0, Flash 8+

 

Mnożnik do użycia, aby zeskalować wyporność x z mapującej kalkulacji.

import flash.filters.DisplacementMapFilter;
import flash.display.BitmapData;
import flash.geom.Point;
import flash.geom.Matrix;
import flash.geom.ColorTransform;

var klipFilmowy:MovieClip = createDisplacementMapRectangle();

klipFilmowy.onPress = function() {
    var filter:DisplacementMapFilter = this.filters[0];
    filter.scaleX = 5;
    this.filters = new Array(filter);
}

function createDisplacementMapRectangle():MovieClip {
    var mapBitmap:BitmapData = createGradientBitmap(300, 80, 0xFF000000, "radial");
    var filter:DisplacementMapFilter = new DisplacementMapFilter(mapBitmap, new Point(-30, -30), 1, 1, 10, 10, "wrap", 0x000000, 0x000000);

    var tekst:MovieClip = createTextBlock();
    tekst._x = 30;
    tekst._y = 30;
   
    tekst.filters = new Array(filter);

    return tekst;
}

function createGradientBitmap(w:Number, h:Number, bgColor:Number, type:String, hide:Boolean):BitmapData {
    var mc:MovieClip = this.createEmptyMovieClip("mc", 1);
    var matrix:Matrix = new Matrix();
    matrix.createGradientBox(w, h, 0, 0, 0);

    mc.beginGradientFill(type, [0xFF0000, 0x0000FF], [100, 100], [0x55, 0x99], matrix, "pad");
    mc.lineTo(w, 0);
    mc.lineTo(w, h);
    mc.lineTo(0, h);
    mc.lineTo(0, 0);
    mc.endFill();
    (hide == true) ? mc._alpha = 0 : mc._alpha = 100;
   
    var bmp:BitmapData = new BitmapData(w, h, true, bgColor);
        bmp.draw(mc, new Matrix(), new ColorTransform(), "normal", bmp.rectangle, true);
    mc.attachBitmap(bmp, this.getNextHighestDepth());
   
    return bmp;
}

function createTextBlock():MovieClip {
    var tekst:MovieClip = this.createEmptyMovieClip("tekst", this.getNextHighestDepth());
    tekst.createTextField("txt", this.getNextHighestDepth(), 0, 0, 300, 80);
    tekst.txt.text = "tekst który generowany jest aby stworzyć efekt wybrzuszenia";
    return tekst;
}