Loading:

Światowy dzień książki... IT! [Książki drukowane -40%| Ebooki -50%]

Ostatnio dodane

php Upload dodaw PHP Tworzenia mi Logowanie obiekt Prosty system sz Lista plików z Jak zbudować pr Jak zamienić w IP uzytkownika Obiekt Timer [AS Proste skrypty w

Top 10

1.yp_match 2.crc32() 3.pcntl_fork 4.gzopen() 5.virtual 6.Nowa broń 7.octdec 8.ftp_nlist 9.fgetss() 10.png2wbmp

56853.05

Klasa FileReference [AS 2]

Klasa: FileReference

Kompatybilność: ActionScript 1.0, Flash 8+

Opis

Klasa FileReference zapewnia środki do wysłania oraz pobrania plików pomiędzy komputerem użytkownika a serwerem. Okno dialogowo systemu operacyjnego skłania użytkownika do wybrania pliku do wysłania lub lokalizacji do zapisania. Każdy obiekt FileReference odwołuje się to pojedynczego pliku na użytkownika dysku, oraz zawiera właściwości, które zawierają informacje o rozmiarze, typu, nazwie, daty utworzenia, modyfikacji, oraz typ tworzenia (tylko Macintosh).

Instancje FileReference są tworzone w dwa różne sposoby:

Kiedy użyjesz operatora NEW do konstruktora: var mojFileReference = new FileReference();
Kiedy użyjesz FileReferenceList.browse(), który tworzy tablicę obiektów FileReference.

Podczas operacji wysyłania, wszystkie właściwości obiektu FilteReference są ustawione przez wezwanie FileReference.browse() lub FileReferenceList.browse(). Podczas pobierania pliku, tylko właściwość name jest ustawiona, kiedy zdarzenie onSelect nastąpi, wszystkie inne właściwości staja się dostępne po zdarzeniu onComplete .

Metoda FileReference.browse() pozwala ci na wybranie jednego pliku, natomiast metoda FileReferenceList.browse() pozwala na zaznaczenie więcej niż jednego pliku. Po poprawnym wywołaniu metody browse() wystarczy wywołać metode FileReference.upload() aby zacząć pobierać jeden plik na raz. Metoda FileReference.download() wyświetla dla użytkownika okno dialogowe (podobne do browse ()), aby wybrać lokalizacje do zapisania pliku, oraz wykonuje zapis.

UWAGA! Klasy FileReference oraz FileReferenceList nie pozwalają Ci na ustawienie domyślnej lokalizacji w oknie dialogowym (ścieżka w systemie). Nie możesz również odczytać pobieranego pliku lub go nadpisywać.

Uwaga klasa FileReference nie działa poprawnia na plaformach: Flash Player dla Linux, Flash Player plug-in dla Mac OS X, zewnętrzny Flash Player dla Macintosh, oraz wersja osamotniona dla Mac OS X 10.1 oraz wcześniejszych. SWF natomias zadziała na wszystkich wersjach Windows oraz wersjach samotnych odtwarzacza dla Macintosh naMac OS X 10.2 oraz późniejszych.

Dostępne właściwości dla klasy FileReference

Nazwa	Opis
creationDate`:`Date [odczyt-tylko]	Zwraca datę utworzenia pliku na dysku.
creator`:`String [odczyt-tylko]	Zwraca typ tworzenia dla Macintosh pliku.
modificationDate`:`Date [odczyt-tylko]	Zwraca datę modyfikacji pliku na dysku.
name`:`String [odczyt-tylko]	Zwraca nazwe pliku na dysku.
postData`:`String	Zwraca parametry POST do operacji wysyłania lub pobierania.
size`:`Number [odczyt-tylko]	Zwraca wilekość pliku na dysku w bajtach.
type`:`String [odczyt-tylko]	Zwraca typ pliku na dysku.

Dostępne zdarzenia dla klasy FileReference

Zdarzenie	Opis
onCancel `= function(plikRef:`FileReference`) {}`	Wywołuje się, gdy użytkownik zamknie okno wyboru pliku bez wybrania pliku.
onComplete `= function(plikRef:`FileReference`) {}`	Wywołuje się, gdy wysyłanie lub pobieranie zakończą się pomyślnie.
onHTTPError `= function(plikRef:`FileReference`, httpError:`Number`) {}`	Wywołuje się, gdy wysysłanie natrafi na błąd HTTP.
onIOError `= function(plikRef:`FileReference`) {}`	Wywołuje się, gdy nastąpią błędy typu: wejście/wyjście.
onOpen `= function(plikRef:`FileReference`) {}`	Wywołuje się, gdy operacje wysyłanie i pobieranie rozpoczynają się.
onProgress `= function(plikRef:`FileReference`, bajtyZaladowane:`Number`, bajtyWszystkie:`Number`) {}`	Wywołuje się, gdy zostaje wysłana lub odebrana jakaś część pliku.
onSecurityError `= function(plikRef:`FileReference`, errorString:`String`) {}`	Wywołuje się, gdy operacje wysyłania lub odbierania zawodzi z błędów bezpieczeństwa.
onSelect `= function(plikRef:`FileReference`) {}`	Wywołuje się, gdy użytkownik wybierze plik w oknie dialogowym.
onUploadCompleteData `= functionplikRef:`FileReference`, dane:`String`) {}`	Wywołuje się, po otrzymanych danych od serwera, zaraz po zakończeniu wysyłania.

Dostępne metody dla klasy FileReference

Nazwa	Opis
addListener`(sluchacz:`Object`) : Void`	rejestruje obiekt do odbierania notyfikacji o zdarzeniach dla obiektu FileReference.
browse`([listaTypow:`Array`]) :` Boolean	Wyświetla w oknie dialogowym tylko rozszerzenia plików, które zostały sprecyzowane w argumencie.
cancel`() : Void`	Zatrzymuje każda operację wysyłania lub pobierania plików dla obiektu FileReference.
download`(url:`String`, [defaultFileName:`String`]) :` Boolean	Wyświetla okno dialogowe w którym użytkownik może pobrać plik z serwera zdalnego.
removeListener`(sluchacz:`Object`) :` Boolean	Usuwa sluchacza dla obiektu, aby nie otrzymywał dalszych notyfikacji.
upload`(url:`String`, uploadNazwaDanych:`String`, testUpload:`Boolean`) :` Boolean	Rozpoczyna wysyłanie wybranego pliku przez użytkownika do zdalnego serweru.

Listing

//przykład #1

import flash.net.FileReference;

var sluchacz:Object = new Object();
sluchacz.onComplete = function(plik:FileReference) {
trace("onComplete : " + plik.name);
}

var url:String = "http://www.adobe.com/platform/whitepapers/platform_overview.pdf";
var plikRef:FileReference = new FileReference();
plikRef.addListener(sluchacz);
plikRef.download(url, "FlashPlatform.pdf");

// przykład #2

import flash.net.FileReference;

var typy:Array = new Array();
var obrazki:Object = new Object();
obrazki.description = "Zdjęcia (*.jpg, *.jpeg, *.gif, *.png)";
obrazki.extension = "*.jpg; *.jpeg; *.gif; *.png";
typy.push(obrazki);

var textTypy:Object = new Object();
textTypy.description = "Pliki tekstowe (*.txt, *.rtf)";
textTypy.extension = "*.txt;*.rtf";
typy.push(textTypy);

var sluchacz:Object = new Object();

sluchacz.onSelect = function(plik:FileReference):Void {
trace("onSelect: " + plik.name);
if(!plik.upload("http://www.funkcje.net/skrypt-upload.php")) {
trace("Wysyłanie zakończone nie powodzeniem.");
}
}

sluchacz.onCancel = function(plik:FileReference):Void {
trace("onCancel");
}

sluchacz.onOpen = function(plik:FileReference):Void {
trace("onOpen: " + plik.name);
}

sluchacz.onProgress = function(plik:FileReference, bajtyZaladowane:Number, bajtyWszystkie:Number):Void {
trace("onProgress: " + bajtyZaladowane + " / " + bajtyWszystkie);
}

sluchacz.onComplete = function(plik:FileReference):Void {
trace("onComplete: " + plik.name);
}

sluchacz.onHTTPError = function(plik:FileReference):Void {
trace("onHTTPError: " + plik.name);
}

sluchacz.onIOError = function(plik:FileReference):Void {
trace("onIOError: " + plik.name);
}

sluchacz.onSecurityError = function(plik:FileReference, errorString:String):Void {
trace("onSecurityError: " + plik.name + " błąd: " + errorString);
}

var plikRef:FileReference = new FileReference();
plikRef.addListener(sluchacz);
plikRef.browse(typy);