Klasa: FileReference

Kompatybilność: ActionScript 1.0, Flash 8+

 

download(url:String, [domyslnaNazwaPliku:String]) : Boolean

 

Opis

 

Wyświetla okno dialogowe w którym użytkownik może pobrać plik z serwera zdalnego.

 

Wyłącznie jedna sesja browse() lub download() może być wykonywana w jednym czasie.

 

Ta metoda wspiera ściąganie każdego typu pliku przez HTTP lub HTTPS.

 

Zwraca TRUE jeśli okno dialogowe zostało otwarte pomyślnie, w innym przypadku zwraca FALSE.

 

Parametry

 

url:String - Ścieżka URL do wybranego pliku do pobrania np: http://www.funkcje.net/zdjecie.jpg?userID=jdoe Maksymalna ścieżka adresu URL wynosi 256 znaków.

 

domyslnaNazwaPliku:String [opcjonalny] - Domyślna nazwa pliku wyświetlana w oknie dialogowym. Nazwa nie może zawierać znaków: / \ : * ? " < > | %

import flash.net.FileReference;

var sluchacz:Object = new Object();

sluchacz.onSelect = function(plik:FileReference):Void {
    trace("onSelect: " + plik.name);
}

sluchacz.onCancel = function(plik:FileReference):Void {
    trace("onCancel");
}

sluchacz.onOpen = function(plik:FileReference):Void {
    trace("onOpen: " + plik.name);
}

sluchacz.onProgress = function(plik:FileReference, bytesLoaded:Number, bytesTotal:Number):Void {
    trace("onProgress with bytesLoaded: " + bytesLoaded + " bytesTotal: " + bytesTotal);
}

sluchacz.onComplete = function(plik:FileReference):Void {
    trace("onComplete: " + plik.name);
}

sluchacz.onIOError = function(plik:FileReference):Void {
    trace("onIOError: " + plik.name);
}

var plikRef:FileReference = new FileReference();
plikRef.addListener(sluchacz);
var url:String = "http://www.adobe.com/platform/whitepapers/platform_overview.pdf";
if(!plikRef.download(url, "FlashPlatform.pdf")) {
    trace("Okno dialogowe się popsuło.");
}